Clojurians Log v2

Please note that clj-otel adheres where possible to the https://opentelemetry.io/docs/specs/semconv/http/http-metrics/. Is there a documented semantic convention for caller username and token? I think the most straightforward solution for the custom behaviour you describe is to provide your own Ring middleware (or Pedestal interceptors) to use instead of wrap-request-duration. As an implementation note, io.opentelemetry/server-request-attrs stores data common to both traces and metrics.

My understanding is that the semantic conventions are intended to ensure that commonly defined concepts have common names, not that the attributes that can be associated with a given metric (or span) is closed. What I'm looking for is a way of adding arbitrary attributes to the metrics, not formally extend otel or have clj-otel embrace or define additional attributes.

That's what I'll end up trying to do: I won't want to hard-code anything in the implementation. There will be some mechanism for adding attributes that are specific to scenario/handler/route/what-have-you.

Thanks for the pointer to io.opentelemetry/server-request-attrs

You are on the right track. There are two particular annoyances of the Java implementation that clj-otel works around through storing data in the request map: • Trace and metrics data are write only and cannot be read • Metrics values once written cannot be modified e.g. add attributes values

What I ended up doing was this:

(def ^:dynamic *additional-request-attributes* {})

(defn additional-request-attributes []
  *additional-request-attributes*)

(defmacro with-additional-request-attributes
  [attrs & forms]
  `(binding [*additional-request-attributes* (merge *additional-request-attributes* ~attrs)]
     ~@forms))

(defn- record-duration!
  ([start-time server-request-attrs status]
   (record-duration! start-time server-request-attrs status (context/dyn)))
  ([start-time server-request-attrs status context]
   (let [attributes (merge (additional-request-attributes)
                           (request-duration-or-size-attrs server-request-attrs status))]
     (instrument/record! @request-duration
                         {:value (since-seconds! start-time)
                          :attributes attributes
                          :context context}))))

(defn- record-request-size!
  ([server-request-attrs status] (record-request-size! server-request-attrs status (context/dyn)))
  ([server-request-attrs status context]
   (when-let [size (get server-request-attrs HttpIncubatingAttributes/HTTP_REQUEST_BODY_SIZE)]
     (let [attributes (merge (additional-request-attributes)
                             (request-duration-or-size-attrs server-request-attrs status))]
       (instrument/record! @request-size
                           {:value size
                            :attributes attributes
                            :context context})))))

(defn wrap-auth-claims-attributes [handler]
  (fn [req]
    (if-let [claims (:auth-claims req)]
      (let [attrs (select-keys claims ["aud" "sub"])]
        (metrics.http.server/with-additional-request-attributes attrs
          (handler req)))
      (handler req))))