post a full router instead of a stub — i want to rule out the possibility of you including a root route and accidentally introducing an extra slash

(def app
  (ring/ring-handler
   (ring/router
    [["/" {:tags "root"}
      ["/:doc-id" {:post {:handler (fn [{:keys [path-params]}]
                                     {:status 200
                                        ;; :headers {"Content-Type" "image/png"}
                                      :body path-params})}}]]
     ["/swagger.json"
      {:get {:no-doc true
             :swagger {:info {:title "my-api"
                              :description "with reitit-ring"}}
             :handler (swagger/create-swagger-handler)}}]

     ]

    {;;:reitit.middleware/transform dev/print-request-diffs ;; pretty diffs
     ;;:validate spec/validate ;; enable spec validation for route data
     ;;:reitit.spec/wrap spell/closed ;; strict top-level validation
     :exception pretty/exception
     :data {:coercion reitit.coercion.spec/coercion
            :muuntaja m/instance
            :middleware [;; swagger feature
                         swagger/swagger-feature
                         ;; query-params & form-params
                         parameters/parameters-middleware
                         ;; content-negotiation
                         muuntaja/format-negotiate-middleware
                         ;; encoding response body
                         muuntaja/format-response-middleware
                         ;; exception handling
                         exception/exception-middleware
                         ;; decoding request body
                         muuntaja/format-request-middleware
                         ;; coercing response bodys
                         coercion/coerce-response-middleware
                         ;; coercing request parameters
                         coercion/coerce-request-middleware
                         ;; multipart
                         multipart/multipart-middleware]}})
   (ring/routes
    (ring/create-resource-handler {:path "/public"})
    (swagger-ui/create-swagger-ui-handler
     {:path "/"
      :config {:validatorUrl nil
               :operationsSorter "alpha"}})
    (ring/create-default-handler))))

bingo, that is exactly it

replace /:doc-id with simply :doc-id

I don’t know how to explain it well in English, so here’s some code denoting how the route tree works

[["/"
  [""]              ; /
  [":doc-id"]]      ; /:doc-id
 ["/swagger.json"]] ; /swagger.jsobn

hmm deosn't seem to like that, must have missed bracket/paren somewhere?

or maybe my handler is invalid

What is the address you visited in your browser? What happens if you run (r/match-by-path your-router "/123")

Oh I think I see the issue now

/:doc-id and /swagger.json are conflicting paths. Set either one to :conflicting true

Here’s an example from my clojurescript REPL

cljs.user> (-> (r/router
                [["/"
                  ["" {:name ::root}]
                  [":id" {:name ::root.id
                          :conflicting true}]]
                 ["/swagger.json" {:name ::swagger
                                   :conflicting true}]])
               (r/match-by-path "/123"))               
#reitit.core.Match{:template "/:id", :data {:name :cljs.user/root.id, :conflicting true}, :result nil, :path-params {:id "123"}, :path "/123"}

The reason this happens is because path params are strings (until you coerce them), so reitit has no way to tell whether you wanted /:id or /swagger.json when gets a path like / + string . By setting the paths as conflicting, reitit will know ahead of time that it will have to resolve the conflict

cf. https://cljdoc.org/d/metosin/reitit/0.5.18/doc/basics/route-conflicts

getting further now , now my swagger is http 405:

[["/" 
      ["" {:name ::root}]
      [":doc-id" {:name ::root.doc-id
                  :conflicting true
                  }]]
     ["/swagger.json"
      {:name ::swagger
       :conflicting true
       :get {:no-doc true
             :swagger {:info {:title "my-api"
                              :description "with reitit-ring"}}
             :handler (swagger/create-swagger-handler)}}]

     ]

sre.zomgd.core> (reitit.core/match-by-path app "/123")
Execution error (IllegalArgumentException) at reitit.core/eval54459$fn$G (core.cljc:38).
No implementation of method: :match-by-path of protocol: #'reitit.core/Router found for class: clojure.lang.AFunction$1

metosin/reitit {:mvn/version "0.4.2"}

i think my router is typo'd perhaps going to start from scratch and see + upgrade to latest version

Place the /swagger.json route before the /:id route

Conflict resolution algorithm isn’t documented well in Reitit, unfortunately. But in short, the first match wins in a conflict.

That is to say, if we have

[["/:id"]
 ["/swagger.json"]]

[["/swagger.json"]
 ["/:id"]]

For reference, I am using [metosin/reitit "0.5.18"] , also the latest version of the library.

@U5Y86G3KL Here is a demonstration of the first match winning in a conflict

cljs.user> (def router 
             (r/router
              [["/swagger.json" {:conflicting true}]
               ["/:id" {:conflicting true}]]))
#'cljs.user/router
cljs.user> (:template (r/match-by-path router "/123"))
"/:id"
cljs.user> (:template (r/match-by-path router "/swagger.json"))
"/swagger.json"

hey @U0479UCF48H moving swagger above :doc-id + :conflicting true did the trick! tysm for your help 🙏