2024-02-10 code-reviews | Clojure Slack Archive

code-reviews 2024-02-10

pez 2024-02-10T11:17:41.486119Z

I need to split/partition some lists based on wether they match a regex. I need only two lists back, [matching, not-matching]. This springs to mind:

(defn- bisect-all-by [pred coll]
  (let [matching (filter pred coll)
        not-matching (remove pred coll)]
    [matching not-matching]))

(defn- partition-all-by [pred coll]
  (->> coll (group-by pred) vals))

(comment
  (bisect-all-by #(< (count %) 6) ["apple" "banana" "cherry" "date" "elderberry" "date"])
  ;; => [("apple" "date" "date") ("banana" "cherry" "elderberry")]
  (bisect-all-by #(re-find #"[an]" %) ["apple" "banana" "cherry" "date" "elderberry" "date"])
  ;; => [("apple" "banana" "date" "date") ("cherry" "elderberry")]
  (bisect-all-by identity ["apple" "banana" "cherry" "date" "elderberry" "date"])
  ;; => [("apple" "banana" "cherry" "date" "elderberry" "date") ()]

  (partition-all-by #(< (count %) 6) ["apple" "banana" "cherry" "date" "elderberry" "date"])
  ;; => (["apple" "date" "date"] ["banana" "cherry" "elderberry"])
  (partition-all-by #(re-find #"[an]" %) ["apple" "banana" "cherry" "date" "elderberry" "date"])
  ;; => (["apple" "banana" "date" "date"] ["cherry" "elderberry"])
  (partition-all-by identity ["apple" "banana" "cherry" "date" "elderberry" "date"])
  ;; => (["apple"] ["banana"] ["cherry"] ["date" "date"] ["elderberry"])

  :rcf)

Both work fine for my use case. And I don’t much need any lazyness. But I’m curious about what you other peeps think are the trade-offs/problems with these and what alternatives you would consider.

2024-02-10T12:20:50.760739Z

Maps, like those produced by group-by, are unordered

🙏 1

tomd 2024-02-10T12:25:48.222469Z

If you're only ever supplying predicates (which return true or false) then group-by will return an ordered array-map (because the number of groups is small). But yeah, it's relying on an implementation detail. Being explicit is probably better:

(defn true+false-groups [pred coll]
  (let [{t true f false} (group-by pred coll)]
    [t f]))

And using the word partition in the name may be confusing to clojurians because in core that means keeping everything in the original order, despite the partitions being there. Whereas group-by based approaches don't

pez 2024-02-10T14:18:56.949489Z

Thanks! The unordered thing would bite me hard if the implementation change. 😃

Clojurians Log v2

code-reviews 2024-02-10